Diagrams Property

Description

Gets the Diagrams collection object. This contains all the chart's diagrams.

Property Type

Read-only property

Syntax (Visual Basic)

Public Property Diagrams() As [ChartDiagramCollection](XtremeChartControl~ChartDiagramCollection.md)

Return Type

Gets the ChartDiagramCollection collection object. This contains all the chart's diagrams.

Remarks

The chart by default has one diagram that you don't have to add. This is the diagram that is worked with when adding a series. The chart can, however, contain multiple diagrams in the same view.

Multiple Diagram Charts are charts that have multiple regions which compare similar data sets side by side (in separate panels) rather than right on top of each other.

Multiple Diagrams

Example

This sample shows how to add 3 diagrams to the chart, which will create the diagram in the picture above.

Dim pContent As ChartContent  
Set pContent = ChartControl.Content

pContent.Legend.Visible = True  
pContent.Legend.VerticalAlignment = xtpChartLegendFarOutside  
pContent.Legend.HorizontalAlignment = xtpChartLegendCenter  
pContent.Legend.Direction = xtpChartLegendLeftToRight

ChartControl.Content.Titles.Add "Total Hours Worked"  

Dim pDiagram1 As New ChartDiagram2D  
pContent.Diagrams.Add pDiagram1  

Dim pDiagram2 As New ChartDiagram2D  
pContent.Diagrams.Add pDiagram2  

Dim pDiagram3 As New ChartPieDiagram  
pContent.Diagrams.Add pDiagram3

Dim pSeries As ChartSeries  
Set pSeries = pContent.Series.Add("Daily")  
Set pSeries.Style = New ChartBarSeriesStyle

pSeries.Points.Add "1 January", 8  
pSeries.Points.Add "2 February", 7  
pSeries.Points.Add "3 March", 6  
pSeries.Points.Add "4 April", 7  
pSeries.Points.Add "5 May", 7  
Set pSeries.Diagram = pDiagram1  
pDiagram1.Rotated = True

Set pSeries = pContent.Series.Add("Summary")  
Set pSeries.Style = New ChartLineSeriesStyle  

Dim pLabel As ChartPointSeriesLabel  
Set pLabel = pSeries.Style.Label

pLabel.LineLength = 20  
pLabel.Angle = 70  

pSeries.Points.Add "1 January", 8  
pSeries.Points.Add "2 February", 8 + 7  
pSeries.Points.Add "3 March", 8 + 7 + 6  
pSeries.Points.Add "4 April", 8 + 7 + 6 + 7  
pSeries.Points.Add "5 May", 8 + 7 + 6 + 7 + 7  
Set pSeries.Diagram = pDiagram2  
pDiagram2.Rotated = True

pDiagram1.AxisX.Title.Visible = True  
pDiagram1.AxisX.Title.Text = "Date"

pDiagram1.AxisY.Title.Visible = True  
pDiagram1.AxisY.Title.Text = "Hours"

pDiagram2.AxisY.Title.Visible = True  
pDiagram2.AxisY.Title.Text = "Hours"  
pDiagram2.AxisX.Title.Visible = False

Set pSeries = pContent.Series.Add("Overview")  
Set pSeries.Style = New ChartPieSeriesStyle

pSeries.Points.Add "1 January", 8  
pSeries.Points.Add "2 February", 7  
pSeries.Points.Add "3 March", 6  
pSeries.Points.Add "4 April", 7  
pSeries.Points.Add "5 May", 7  
Set pSeries.Diagram = pDiagram3

Dim pPieLabel As ChartPieSeriesLabel  
Set pPieLabel = pSeries.Style.Label  

On Error Resume Next:  
pPieLabel.Position = xtpChartPieLabelRadial